#!/usr/bin/apple1basic
LOMEM=768
   10 PRINT "CRAP GAME"
   20 PRINT "WITH THE COMPUTER AS YOUR OPPONENT. THE RULES ARE SIMPLE:"
   30 PRINT "   *A 7 OR 11 ON THE FIRST ROLL WINS"
   40 PRINT "   *A 2, 3, OR 12 ON THE FIRST ROLL LOSES"
   50 PRINT 
   60 PRINT "ANY OTHER NUMBER ROLLED BECOMES YOUR 'POINT' . YOU CONTINUE"
   70 PRINT "TO ROLL...IF YOU GET YOUR POINT, YOU WIN. IF YOU ROLL A 7,"
   80 PRINT "YOU LOSE. THE DICE CHANGE HANDS WHEN THIS HAPPENS."
  110 PRINT "WHAT NUMBER BETWEEN 1 AND 711 IS LUCKY FOR YOU TODAY";
  120 INPUT N
  130 FOR I=1 TO N
  140 LET X= RND (I)
  150 NEXT I
  160 LET Z=5*10+11* RND (I)
  170 PRINT "SPLENDID.....YOU ARE GIVEN ";Z;" DOLLARS TO PLAY WITH."
  180 PRINT 
  190 PRINT 
  200 REM  IF N IS EVEN 'YOU' ROLL FIRST, IF N IS ODD 'I' ROLL FIRST. 
  210 IF N-2*N/2=0 THEN 270
  220 LET W=-1
  230 PRINT "I'LL ROLL FIRST....."
  240 PRINT 
  250 PRINT 
  260 GOTO 310
  270 LET W=1
  280 PRINT "YOU ROLL FIRST....."
  290 PRINT 
  300 PRINT 
  310 LET Q=0
  320 PRINT "HOW MUCH DO YOU BET ($$) ";
  330 INPUT B
  340 PRINT "OK....."
  350 PRINT 
  400 IF B=0 THEN 1080
  410 IF B<Z+1 THEN 440
  420 PRINT "DON'T TRY TO BET MORE THAN YOU HAVE, PLEASE!!"
  430 GOTO 320
  440 LET D1= RND (6)+1
  450 LET D2= RND (6)+1
  460 LET Q=Q+1
  470 LET S=D1+D2
  480 IF W>0 THEN 510
  490 PRINT "  I ROLL ";D1;" AND ";D2;
  500 GOTO 520
  510 PRINT "YOU ROLL ";D1;" AND ";D2;
  520 IF Q<>1 THEN 840
  530 IF (S-2)*(S-3)*(S-12)=0 THEN 620
  540 IF (S-7)*(S-11)=0 THEN 690
  550 IF W>0 THEN 580
  560 PRINT " SO MY POINT IS ";S;
  570 GOTO 590
  580 PRINT " SO YOUR POINT IS ";S;
  590 PRINT ".....LET'S ROLL 'EM AGAIN....."
  600 LET P=S
  610 GOTO 440
  620 PRINT " AND CRAP OUT..."
  630 LET C=1
  640 IF W>0 THEN 670
  650 LET Z=Z+B
  660 GOTO 750
  670 LET Z=Z-B
  680 GOTO 750
  690 PRINT " AND PASS....."
  700 LET C=1
  710 IF W>0 THEN 740
  720 LET Z=Z-B
  730 GOTO 750
  740 LET Z=Z+B
  750 PRINT 
  760 IF Z<1 THEN 1040
  770 PRINT "YOU NOW HAVE ";Z;" DOLLARS LEFT....."
  780 IF C>0 THEN 810
  790 PRINT "CHANGE DICE NOW....."
  800 PRINT 
  810 LET W=W*C
  820 LET Q=0
  830 GOTO 320
  840 IF S<>7 THEN 920
  850 PRINT " AND LOSE....."
  860 LET C=-1
  870 IF W>0 THEN 900
  880 LET Z=Z+B
  890 GOTO 750
  900 LET Z=Z-B
  910 GOTO 750
  920 IF S=P THEN 950
  930 PRINT "...ROLL AGAIN....."
  940 GOTO 440
  950 IF W>0 THEN 1000
  960 PRINT " AND MAKE MY POINT....."
  970 LET C=1
  980 LET Z=Z-B
  990 GOTO 750
 1000 PRINT " AND MAKE YOUR POINT....."
 1010 LET C=1
 1020 LET Z=Z+B
 1030 GOTO 750
 1040 PRINT 
 1050 PRINT "YOU HAVE RUN OUT OF MONEY....SORRY ABOUT THAT....."
 1060 PRINT "THANKS FOR THE GAME.....BETTER LUCK NEXT TIME, PARDNER!"
 1070 GOTO 2000
 1080 PRINT "THANKS FOR THE GAME.....AND CONGRATULATIONS"
 1090 PRINT "FOR BEING ABLE TO QUIT WHILE YOU WERE AHEAD."
 2000 END